home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / mac / files / dsp / 56000tar.z / 56000tar / 56000 / speech / adpcmns.asm < prev    next >
Assembly Source File  |  1991-11-26  |  55KB  |  1,556 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ;**************************************************************************
  7. ;
  8. ;   ADPCMNS.ASM       Full-Duplex 32-kbit/s Nonstandard CCITT ADPCM
  9. ;
  10. ; Version 1.0 - 8/9/90
  11. ;
  12. ; This program implements the algorithm defined in CCITT Recommendation
  13. ; G.721: "32 kbit/s Adaptive Differential Pulse Code Modulation" dated
  14. ; August 1986.  This code contains a real-time I/O interface for a
  15. ; hardware platform consisting of two DSP56000ADS boards, each connected
  16. ; to an MC145503 codec.
  17. ;
  18. ; Please refer to the file ADPCMNS.HLP for further information about
  19. ; this program.  Also refer to Motorola Application Report APR9/D for
  20. ; complete documentation.
  21. ;
  22. ;**************************************************************************
  23.  
  24.             OPT     CC,CEX
  25.                                                                          
  26. START       EQU     $0020
  27. PBDDR       EQU     $FFE2
  28. PBD         EQU     $FFE4
  29. PCC         EQU     $FFE1
  30. CRA         EQU     $FFEC
  31. CRB         EQU     $FFED
  32. SSISR       EQU     $FFEE
  33. SSIRX       EQU     $FFEF
  34. SSITX       EQU     $FFEF
  35. BCR         EQU     $FFFE
  36.  
  37.             ORG     X:$0000
  38.  
  39. ;******************** Encoder variables ***********************************
  40. ;   I = siii 0000 | 0000 0000 | 0000 0000 (ADPCM format)
  41. I_T         DS      1               ;ADPCM codeword
  42. ;   DQ = siii iiii | iiii iii.f | ffff ffff  (24SM)
  43. DQ_T        DS      1               ;Quantized difference signal
  44. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  45. Y_T         DS      1               ;Quantizer scale factor
  46. ;   AP = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  47. AP_T        DS      1               ;Unlimited speed control parameter
  48. ;   AL = 0i.ff ffff | ffff ffff | ffff ffff  (23SM)
  49. AL_T        DS      1               ;Limited speed control parameter
  50.  
  51. ;******************** Decoder variables ***********************************
  52. I_R         DS      1               ;ADPCM codeword
  53. DQ_R        DS      1               ;Quantized difference signal
  54. Y_R         DS      1               ;Quantizer scale factor
  55. AP_R        DS      1               ;Unlimited speed control parameter
  56. AL_R        DS      1               ;Limited speed control parameter
  57.  
  58. ;******************** Temporary variables *********************************
  59. ;   IMAG = 0000 0000 | 0000 0000 | 0000 0iii.
  60. IMAG        DS      1               ;|I|
  61. ;   PKS1 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  62. PKS1        DS      1               ;XOR of  PK0 & PK1
  63. ;   PKS2 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  64. PKS2        DS      1               ;XOR of  PK0 & PK2
  65. DATAPTR_T   DS      1               ;Transmit data buffer pointer
  66. DATAPTR_R   DS      1               ;Receive data buffer pointer
  67.  
  68. ;******************** Table for quantizing DLN ****************************
  69. ; Used in QUAN routine
  70.  
  71. QUANTAB     DS      8
  72.  
  73. ;******************** Table for unquantizing I ****************************
  74. ; Used in RECONST
  75.  
  76. IQUANTAB    DS      8
  77.  
  78. ;******************** W(I) lookup table ***********************************
  79. ; Used in FUNCTW routine
  80.  
  81. WIBASE      DS      8
  82.  
  83. ;******************** F(I) lookup table ***********************************
  84. ; Used in FUNCTF routine
  85.  
  86. FIBASE      DS      8
  87.  
  88. ;******************** Table used in COMPRESS ******************************
  89.  
  90. TAB         DS      8
  91.  
  92. ;******************** Encoder data buffer *********************************
  93. ;   DQ = siii iiii | iiii iiii. | ffff ffff  (24TC)
  94. ;   SRn in same format
  95.  
  96. DATA_T      DSM     8                   ;8 word modulo buffer for data,
  97.                                         ; R2 is used as pointer, DATAPTR_T
  98.                                         ; points to start of buffer (DQ1)
  99.                                         ; at beginning of cycle
  100.  
  101. ;******************** Decoder data buffer *********************************
  102.  
  103. DATA_R      DSM     8                   ;8 word modulo buffer for data
  104.                                         ; (same format as DATA_T)
  105.  
  106.  
  107.             ORG     Y:$0000
  108. ;******************** Encoder variables ***********************************
  109. ;   SE = siii iiii | iiii iiii. | ffff ffff  (24TC)
  110. SE_T        DS      1               ;Signal estimate
  111. ;   SEZ = siii iiii | iiii iiii. | ffff ffff (24TC)
  112. SEZ_T       DS      1               ;Partial signal estimate
  113. ;   SR = siii iiii | iiii iiii. | ffff ffff  (24TC)
  114. SR_T        DS      1               ;Reconstructed signal
  115. ;   PK0 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  116. PK0_T       DS      1               ;Sign of DQ + SEZ
  117. ;   PK1 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  118. PK1_T       DS      1               ;Delayed sign of DQ + SEZ
  119. ;   DMS = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  120. DMS_T       DS      1               ;Short term average of F(I)
  121. ;   DML = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  122. DML_T       DS      1               ;Long term average of F(I)
  123. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  124. TDP_T       DS      1               ;Tone detect
  125. ;   TD = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  126. TD_T        DS      1               ;Delayed tone detect
  127. ;   YU =  0iii i.fff | ffff ffff | ffff ffff  (23SM)
  128. YU_T        DS      1               ;Fast quantizer scale factor
  129. ;   YL =  0iii i.fff | ffff ffff | ffff ffff  (23SM)
  130. YL_T        DS      1               ;Slow quantizer scale factor
  131. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  132. SIGPK_T     DS      1               ;Sgn[p(k)] flag
  133. ;   A2P = si.ff ffff | ffff ffff | ffff ffff (24TC)
  134. A2P_T       DS      1               ;Second order predictor coef
  135. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  136. TR_T        DS      1               ;Transition detect
  137. ;   S = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  138. S_T         DS      1               ;Input PCM signal
  139.  
  140. ;******************** Decoder variables ***********************************
  141. SE_R        DS      1               ;Signal estimate
  142. SEZ_R       DS      1               ;Partial signal estimate
  143. SR_R        DS      1               ;Reconstructed signal
  144. PK0_R       DS      1               ;Sign of DQ + SEZ
  145. PK1_R       DS      1               ;Delayed sign of DQ + SEZ
  146. DMS_R       DS      1               ;Short term average of F(I)
  147. DML_R       DS      1               ;Long term average of F(I)
  148. TDP_R       DS      1               ;Tone detect
  149. TD_R        DS      1               ;Delayed tone detect
  150. YU_R        DS      1               ;Fast quantizer scale factor
  151. YL_R        DS      1               ;Slow quantizer scale factor
  152. SIGPK_R     DS      1               ;Sgn[p(k)] flag
  153. A2P_R       DS      1               ;Second order predictor coef
  154. TR_R        DS      1               ;Transition detect
  155. SP_R        DS      1               ;Output PCM signal
  156.  
  157. ;******************** Temporary variables *********************************
  158. DQMAG       DS      1               ;|DQ|
  159. SL_T        DS      1               ;PCM input for encoder
  160. LAW         DS      1               ;PCM mode select
  161.  
  162. ;******************** Shift constant lookup table *************************
  163. ; Shift constants used for doing left or right shifts by multiplying by a
  164. ; power of 2.
  165.  
  166. RSHFT       DS      24
  167. LSHFT
  168.  
  169. ;******************** Encoder coef. buffer ********************************
  170. ;   Bn = si.ff ffff | ffff ffff | ffff ffff (24TC)
  171. ;   An in same format
  172.                                     ;8 word modulo buffer for coefs.,
  173.                                     ; R6 is used as pointer
  174. COEF_T      DSM     8               ;B1
  175.                                     ;B2
  176.                                     ;B3
  177.                                     ;B4
  178.                                     ;B5
  179.                                     ;B6
  180.                                     ;A1
  181.                                     ;A2
  182.  
  183. ;******************** Decoder coef. buffer ********************************
  184.                                     ;8 locations for coef. queue
  185.                                     ; (same format as COEF_T)
  186. COEF_R      DSM     8               ;B1
  187.                                     ;B2
  188.                                     ;B3
  189.                                     ;B4
  190.                                     ;B5
  191.                                     ;B6
  192.                                     ;A1
  193.                                     ;A2
  194.  
  195.             PAGE
  196.  
  197.             ORG     P:$0000
  198.             JMP     START
  199.  
  200.             ORG     P:START
  201.  
  202.         MOVEC   #$06,OMR            ;Set DE=1
  203.         CLR     A
  204.         MOVEP   A,X:BCR             ;Set BCR for 0 wait states
  205.         JSR     INIT
  206.  
  207. ;**************************************************************************
  208. ;
  209. ; Poll SSI for receiver data available.  Note that the SSI transmit and
  210. ; receive are synchronous.
  211. ;
  212. ;**************************************************************************
  213.  
  214. IOWAIT  JCLR    #7,X:SSISR,IOWAIT   ;Wait for SSIRX full
  215.         MOVE    Y:SP_R,A            ;Get decoder output
  216.         MOVEP   A,X:SSITX           ;Send PCM output to CODEC
  217.         MOVEP   X:SSIRX,A           ;Get input sample
  218.         MOVE    A,Y:S_T             ;Save PCM input for encoder
  219.  
  220. ;**************************************************************************
  221. ;
  222. ;   Encoder
  223. ;
  224. ;**************************************************************************
  225.  
  226. ENCODE  MOVE    X:DATAPTR_T,R2      ;Set data pointer to DQ1EXP
  227.         MOVE    #COEF_T,R6          ;Set coef pointer to B1
  228.         JSR     <PRDICT             ;(FMULT,ACCUM)
  229.         MOVE    B,Y:SEZ_T
  230.         MOVE    A,Y:SE_T
  231.  
  232.         MOVE    X:AP_T,A
  233.         MOVE    Y:YL_T,Y1
  234.         MOVE    Y:YU_T,Y0
  235.         JSR     <LIMAMIX            ;(LIMA,MIX)
  236.         MOVE    X1,X:AL_T
  237.         MOVE    A,X:Y_T
  238.  
  239. ;********************************************
  240. ; Get encoder input (PCM data)
  241.  
  242.         MOVE    Y:S_T,A
  243.  
  244. ;********************************************
  245.  
  246.         MOVE    Y:SE_T,B
  247.         MOVE    X:Y_T,Y0
  248.         JSR     <CONVERT            ;(EXPAND,SUBTA,LOG,SUBTB,QUAN)
  249.         MOVE    A,X:I_T
  250.         
  251. ;********************************************
  252. ; Output ADPCM word
  253.  
  254.         MOVE    A,X1    Y:RSHFT+20,Y0
  255.         MPY     Y0,X1,A             ;Shift ADPCM word to LSB's
  256.         MOVEP   A1,X:PBD            ;Put output on PB0..3
  257.         MOVE    X:I_T,A
  258.  
  259. ;********************************************
  260.  
  261.         MOVE    X:Y_T,B
  262.         JSR     <IQUAN              ;(RECONST,ADDA,ANTILOG)
  263.         MOVE    A1,X:DQ_T
  264.  
  265.         MOVE    Y:TD_T,A
  266.         MOVE    Y:YL_T,B
  267.         JSR     <TRANS              ;(TRANS)
  268.         MOVE    A1,Y:TR_T
  269.  
  270.         MOVE    Y:SE_T,B
  271.         MOVE    X:DQ_T,A
  272.         MOVE    Y:SEZ_T,X0
  273.         MOVE    #PK1_T,R0
  274.         JSR     <ADDBC              ;(ADDB,ADDC)
  275.         MOVE    X1,Y:SR_T
  276.         MOVE    B1,Y:SIGPK_T
  277.  
  278.         MOVE    X:DQ_T,Y0
  279.         JSR     <UPB                ;(XOR,UPB)
  280.  
  281.         MOVE    Y:SIGPK_T,X0
  282.         JSR     <UPA2               ;(UPA2,LIMC)
  283.         MOVE    A,Y:A2P_T
  284.         MOVE    A,Y:(R6)-           ;Save A2P to A2
  285.  
  286.         MOVE    Y:SIGPK_T,X1
  287.         MOVE    Y:A2P_T,X0
  288.         JSR     <UPA1               ;(UPA1,LIMD)
  289.  
  290.         MOVE    X:DQ_T,A
  291.         MOVE    Y:SR_T,B
  292.         JSR     <FLOAT              ;(FLOATA,FLOATB)
  293.  
  294.         MOVE    Y:A2P_T,B
  295.         MOVE    Y:TR_T,Y0
  296.         JSR     <TONE               ;(TONE,TRIGB)
  297.         MOVE    Y1,Y:TDP_T
  298.         MOVE    A,Y:TD_T
  299.  
  300.         MOVE    Y:DMS_T,Y0
  301.         MOVE    Y:DML_T,Y1
  302.         JSR     <FUNCTF             ;(FUNCTF,FILTA,FILTB)
  303.         MOVE    A,Y:DMS_T
  304.         MOVE    B,Y:DML_T
  305.  
  306.         MOVE    Y:TDP_T,X1
  307.         MOVE    X:Y_T,Y1
  308.         JSR     <SUBTC              ;(SUBTC)
  309.  
  310.         MOVE    X:AP_T,X1
  311.         MOVE    Y:TR_T,Y1
  312.         JSR     <FILTC              ;(FILTC,TRIGA)
  313.         MOVE    A1,X:AP_T
  314.  
  315.         MOVE    X:Y_T,Y0
  316.         MOVE    Y:YL_T,Y1
  317.         JSR     <FUNCTW             ;(FUNCTW,FILTD,LIMB,FILTE)
  318.         MOVE    X0,Y:YU_T
  319.         MOVE    A1,Y:YL_T
  320.  
  321.         MOVE    R2,X:DATAPTR_T      ;Save transmit data pointer
  322.  
  323. ;**************************************************************************
  324. ;
  325. ;   Decoder
  326. ;
  327. ;**************************************************************************
  328.  
  329. DECODE  MOVE    X:DATAPTR_R,R2      ;Set data pointer to DQ1EXP
  330.         MOVE    #COEF_R,R6          ;Set coef pointer to B1
  331.         JSR     <PRDICT             ;(FMULT,ACCUM)
  332.         MOVE    B,Y:SEZ_R
  333.         MOVE    A,Y:SE_R
  334.  
  335.         MOVE    X:AP_R,A
  336.         MOVE    Y:YL_R,Y1
  337.         MOVE    Y:YU_R,Y0
  338.         JSR     <LIMAMIX            ;(LIMA,MIX)
  339.         MOVE    X1,X:AL_R
  340.         MOVE    A,X:Y_R
  341.  
  342. ;********************************************
  343. ; Get decoder ADPCM input
  344.  
  345.         MOVEP   X:PBD,X1
  346.         MOVE    Y:LSHFT-16,Y0
  347.         MPY     X1,Y0,A     #<$F0,X0    ;Shift to MSB's of A0
  348.         MOVE    A0,A
  349.         AND     X0,A                ;ADPCM bits in MSB's of A1
  350.         MOVE    A,X:I_R             ;Save decoder input
  351.  
  352. ;********************************************
  353.  
  354.         MOVE    X:Y_R,B
  355.         JSR     <IQUAN              ;(RECONST,ADDA,ANTILOG)
  356.         MOVE    A1,X:DQ_R
  357.  
  358.         MOVE    Y:TD_R,A
  359.         MOVE    Y:YL_R,B
  360.         JSR     <TRANS              ;(TRANS)
  361.         MOVE    A1,Y:TR_R
  362.  
  363.         MOVE    Y:SE_R,B
  364.         MOVE    X:DQ_R,A
  365.         MOVE    Y:SEZ_R,X0
  366.         MOVE    #PK1_R,R0
  367.         JSR     <ADDBC              ;(ADDB,ADDC)
  368.         MOVE    B1,Y:SIGPK_R
  369.         MOVE    X1,Y:SR_R
  370.  
  371.         MOVE    Y:LAW,B
  372.         JSR     <COMPRESS           ;(COMPRESS)
  373.  
  374. ;********************************************
  375. ; Save PCM decoder output (reconstructed signal)
  376.  
  377.         MOVE    A1,Y:SP_R
  378.  
  379. ;********************************************
  380.  
  381.         MOVE    X:DQ_R,Y0
  382.         JSR     <UPB                ;(XOR,UPB)
  383.  
  384.         MOVE    Y:SIGPK_R,X0
  385.         JSR     <UPA2               ;(UPA2,LIMC)
  386.         MOVE    A,Y:A2P_R
  387.         MOVE    A,Y:(R6)-
  388.  
  389.         MOVE    Y:SIGPK_R,X1
  390.         MOVE    Y:A2P_R,X0
  391.         JSR     <UPA1               ;(UPA1,LIMD)
  392.  
  393.         MOVE    X:DQ_R,A
  394.         MOVE    Y:SR_R,B
  395.         JSR     <FLOAT              ;(FLOATA,FLOATB)
  396.  
  397.         MOVE    Y:A2P_R,B
  398.         MOVE    Y:TR_R,Y0
  399.         JSR     <TONE               ;(TONE,TRIGB)
  400.         MOVE    Y1,Y:TDP_R
  401.         MOVE    A,Y:TD_R
  402.  
  403.         MOVE    Y:DMS_R,Y0
  404.         MOVE    Y:DML_R,Y1
  405.         JSR     <FUNCTF             ;(FUNCTF,FILTA,FILTB)
  406.         MOVE    A,Y:DMS_R
  407.         MOVE    B,Y:DML_R
  408.  
  409.         MOVE    Y:TDP_R,X1
  410.         MOVE    X:Y_R,Y1
  411.         JSR     <SUBTC              ;(SUBTC)
  412.  
  413.         MOVE    X:AP_R,X1
  414.         MOVE    Y:TR_R,Y1
  415.         JSR     <FILTC              ;(FILTC,TRIGA)
  416.         MOVE    A1,X:AP_R
  417.  
  418.         MOVE    X:Y_R,Y0
  419.         MOVE    Y:YL_R,Y1
  420.         JSR     <FUNCTW             ;(FUNCTW,FILTD,LIMB,FILTE)
  421.         MOVE    X0,Y:YU_R
  422.         MOVE    A1,Y:YL_R
  423.  
  424.         MOVE    R2,X:DATAPTR_R
  425.  
  426.         JMP     <IOWAIT
  427.  
  428. ;**************************************************************************
  429. ;       FMULT/ACCUM
  430. ;
  431. ; Perform adaptive prediction filter using 24-bit fixed point
  432. ; multiply and 56-bit accumulate
  433. ;
  434. ; SEZ(k) = [B1(k-1) * DQ(k-1)] + ... + [B6(k-1) * DQ(k-6)]
  435. ;        = WB1 + WB2 + ... + WB6
  436. ;
  437. ; SE(k) = SEZ(k) + [A1(k-1) * SR(k-1)] + [A2(k-1) * SR(k-2)]
  438. ;       = SEZ + WA1 + WA2
  439. ;
  440. ; Inputs:
  441. ;   SRn = X:(R2) = siii iiii | iiii iiii. | ffff ffff  (24TC)
  442. ;       (DQ in same format as SR)
  443. ;
  444. ;   An = Y:(R6) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  445. ;       (Bn in same format as An)
  446. ;
  447. ; Outputs:
  448. ;   SEZ = siii iiii | iiii iiii. | ffff ffff  (24TC)
  449. ;   SE = siii iiii | iiii iiii. | ffff ffff  (24TC)
  450. ;
  451. ;**************************************************************************
  452.  
  453. PRDICT  CLR     A       X:(R2)+,X0  Y:(R6)+,Y0  ;Get DQ1 & B1
  454.         REP     #6
  455.         MAC     X0,Y0,A X:(R2)+,X0  Y:(R6)+,Y0  ;Find SEZ
  456.         TFR     A,B                             ;Copy SEZ
  457.         ASL     B                               ;Adjust radix pt.
  458.         MAC     X0,Y0,A X:(R2)+,X0  Y:(R6)+,Y0  ;Accum, get SR2 & A2
  459.         MAC     X0,Y0,A                         ;Find SE
  460.         ASL     A                               ;Adjust radix pt.
  461.         RTS
  462.  
  463. ;**************************************************************************
  464. ;       LIMA
  465. ;
  466. ; Limit speed control parameter
  467. ;
  468. ; AL(k) = 1        if AP(k-1) > 1
  469. ;       = AP(k-1)  if AP(k-1) <= 1
  470. ;
  471. ; Inputs:
  472. ;   AP = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  473. ;
  474. ; Outputs:
  475. ;   AL = 0i.ff ffff | ffff ffff | ffff ffff  (23SM)
  476. ;
  477. ;**************************************************************************
  478.  
  479. LIMAMIX MOVE    #<$20,X0            ;Get '1'
  480.         CMP     X0,A                ;Test AP
  481.         TGT     X0,A                ;If AP>'1' set AL='1'
  482.         ASL     A                   ;Shift to align radix pt.
  483.  
  484. ;**************************************************************************
  485. ;       MIX
  486. ;
  487. ; Form linear combination of fast and slow quantizer
  488. ;   scale factors
  489. ;
  490. ; Y(k) = AL(k) * YU(k-1) + [1 - AL(k)] * YL(k-1)
  491. ;
  492. ; Inputs:
  493. ;   YL = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  494. ;   AL = 0i.ff ffff | ffff ffff | ffff ffff  (23SM)
  495. ;   YU = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  496. ;
  497. ; Outputs:
  498. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  499. ;
  500. ;**************************************************************************
  501.  
  502.         TFR     Y0,A    A,X1        ;Swap YU and AL
  503.         SUB     Y1,A                ;Find YU-YL
  504.         ABS     A       A,B         ;Find |YU-YL|, save sign
  505.         MOVE    A,Y0
  506.         MPY     X1,Y0,A             ;Find PRODM=|YU-YL|*AL
  507.         NEG     A   A,X0            ;Find -PRODM, save PRODM
  508.         TST     B   Y1,B            ;Check sign
  509.         TPL     X0,A                ;If sign=0 PROD=PRODM,
  510.                                     ; else PROD=-PRODM
  511.         ADDL    B,A                 ;Find Y=PROD+YL
  512.         RTS
  513.  
  514. ;**************************************************************************
  515. ;       EXPAND
  516. ;
  517. ; Convert A-law or mu-law PCM to uniform PCM (according to
  518. ;   Recommendation G.711). For further details see Motorola
  519. ;   application bulletin "Logarithmic/Linear Conversion
  520. ;   Routines for DSP56000/1".
  521. ;
  522. ; Input:
  523. ;   S = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  524. ;
  525. ; Output:
  526. ;   SL = siii iiii | iiii ii.00 | 0000 0000  (14TC)
  527. ;
  528. ;**************************************************************************
  529.  
  530. CONVERT MOVE    A,X0    #>$80,Y1    ;Get shift constant
  531.         MPY     X0,Y1,A     #>$7F,X1    ;Shift S to 8 lsb's of A1
  532.         AND     X1,A                ;Mask off sign of S
  533.         MOVE    A1,N3               ;Load |S| as offset
  534.         CMPM    Y1,A                ;Check sign of S
  535.         MOVE    X:(R3+N3),A         ;Lookup |SL| from ROM table
  536.         JGE     <SUBTA              ;If S=0, SL=|SL|
  537.         NEG     A                   ;If S=1, SL=-|SL|
  538.  
  539. ;**************************************************************************
  540. ;       SUBTA
  541. ;
  542. ; Compute difference signal by subtracting signal estimate
  543. ;       from input signal
  544. ;
  545. ;   D(k) = SL(k) - SE(k)
  546. ;
  547. ; Inputs:
  548. ;   SL = siii iiii | iiii ii.00 | 0000 0000  (16TC) 
  549. ;   SE = siii iiii | iiii iiii. | ffff ffff  (24TC)
  550. ;
  551. ; Output:
  552. ;   D = siii iiii | iiii iiii. | ffff ffff  (24TC)
  553. ;**************************************************************************
  554.  
  555. SUBTA   ASR     A                       ;Sign extend SL and
  556.         SUBR    B,A                     ; find D=SL-SE
  557.  
  558. ;**************************************************************************
  559. ;       LOG
  560. ;
  561. ; Convert difference signal from the linear to the log
  562. ;   domain.  Use approximation LOG2[1 + x] = x
  563. ;
  564. ; Input:
  565. ;   D = siii iiii | iiii iiii. | ffff ffff  (24TC)
  566. ;
  567. ; Outputs:
  568. ;   DL = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  569. ;   DS = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  570. ;
  571. ;**************************************************************************
  572.  
  573.         ABS     A   A,Y1                ;Find DQM=|D|, save DS to Y1
  574.         MOVE    Y:RSHFT+15,X0           ;Get '1'
  575.         CMP     X0,A    #<$40,X1        ;Check for DQM<1
  576.         JGE     <NORMEXP
  577.         CLR     A                       ;If DQM<1 set DL=0
  578.         JMP     <SUBTB                  ; and continue
  579. NORMEXP
  580.         MOVE    #$000E,R0               ;Get exp bias (14)
  581.         REP     #14                     ;If DQM!=0, do norm iteration
  582.         NORM    R0,A                    ; 14 times to find MSB of DQM
  583.         EOR     X1,A    Y:LSHFT-19,X0   ;Zero MSB of MANT, get EXP shift
  584.         MOVE    R0,X1                   ;Move EXP to X1
  585.         MPY     X0,X1,A     A,X1        ;Shift EXP<<19, save MANT to X1
  586.         MOVE    Y:RSHFT+3,X0            ;Get shift
  587.         MOVE    A0,A                    ;Move EXP to A1
  588.         MAC     X0,X1,A                 ;Shift MANT>>3 & combine with EXP
  589.  
  590. ;**************************************************************************
  591. ;       SUBTB
  592. ;
  593. ; Scale log version of difference signal by subtracting
  594. ;   scale factor
  595. ;
  596. ; DLN(k) = DL(k) - Y(k)
  597. ;
  598. ; Inputs:
  599. ;   DL = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  600. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  601. ;
  602. ; Output:
  603. ;   DLN = siii i.fff | ffff ffff | ffff ffff  (24TC)
  604. ;
  605. ;**************************************************************************
  606.  
  607. SUBTB   SUB     Y0,A                    ;Find DLN=DL-Y
  608.  
  609. ;**************************************************************************
  610. ;       QUAN
  611. ;
  612. ; Quantize difference signal in log domain
  613. ;
  614. ;    log2|D(k)| - Y(k) | |I(k)|
  615. ;    ------------------+--------
  616. ;      [3.12, + inf)   |   7
  617. ;      [2.72, 3.12)    |   6
  618. ;      [2.34, 2.72)    |   5
  619. ;      [1.91, 2.34)    |   4
  620. ;      [1.38, 1.91)    |   3
  621. ;      [0.62, 1.38)    |   2
  622. ;      [-0.98, 0.62)   |   1
  623. ;      (- inf, -0.98)  |   0
  624. ;
  625. ; Inputs:
  626. ;   DLN = siii i.fff | ffff ffff | ffff ffff  (24TC)
  627. ;   DS = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  628. ;
  629. ; Output:
  630. ;   I = siii 0000 | 0000 0000 | 0000 0000 (ADPCM format)
  631. ;
  632. ;**************************************************************************
  633.  
  634.         MOVE    #QUANTAB,R0         ;Get quantization table base
  635.         MOVE    #>QUANTAB+2,X1      ;Get offset for quan conversion
  636.         MOVE    X:(R0)+,X0          ;Get quan table value
  637. TSTDLN  CMP     X0,A    X:(R0)+,X0  ;Compare to DLN
  638.         JGE     <TSTDLN             ;If value<DLN try next range
  639.         MOVE    R0,A                ;When range found...
  640.                                     ; subtract pointer from
  641.         SUB     X1,A    Y:LSHFT-20,X0   ; base to get IMAG=|I|  
  642.         MOVE    A1,X1
  643.         MPY     X0,X1,A     Y1,B    ;Shift IMAG <<20, result is
  644.                                     ; in A0, move DS (from LOG) into B
  645.         MOVE    A0,A
  646.         TST     A       #<$F0,X0    ;Check IMAG, get invert mask
  647.         JEQ     <INVERT             ;If IMAG=0 invert bits
  648.         TST     B                   ;If IMAG!=0, check DS
  649.         JPL     <IOUT               ;If DS=1 don't invert IMAG
  650. INVERT  EOR     X0,A                ;If DS=0 or IMAG=0 invert IMAG
  651. IOUT    MOVE    A1,A                ;Adjust sign extension
  652.         RTS
  653.  
  654. ;**************************************************************************
  655. ;       RECONST
  656. ;
  657. ; Reconstruct quantized difference signal in the log domain
  658. ;
  659. ;     |I(k)| | log2|DQ(k)| - Y(k)
  660. ;    --------+-------------------
  661. ;       7    |      3.32
  662. ;       6    |      2.91
  663. ;       5    |      2.52
  664. ;       4    |      2.13
  665. ;       3    |      1.66
  666. ;       2    |      1.05
  667. ;       1    |      0.031
  668. ;       0    |      - inf
  669. ;
  670. ; Inputs:
  671. ;   I = iiii 0000 | 0000 0000 | 0000 0000  (ADPCM format)
  672. ;
  673. ; Output:
  674. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  675. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  676. ;   IMAG = 0000 0000 | 0000 0000 | 0000 0iii.
  677. ;
  678. ;**************************************************************************
  679.  
  680. IQUAN   MOVE    A,Y1                ;Save DQS (sign of I) to Y1
  681.         MOVE    #<$F0,X1
  682.         EOR     X1,A    Y:RSHFT+20,Y0   ;Invert bits of I
  683.         TMI     Y1,A                ;If ^IS=1, use I, else use ^I
  684.         MOVE    A1,X0
  685.         MPY     X0,Y0,A     #IQUANTAB,R0    ;Shift IMAG>>20
  686.         MOVE    A1,N0               ;Load IMAG as offset into IQUAN table
  687.         MOVE    A1,X:IMAG           ;Save |I|
  688.         MOVE    X:(R0+N0),A         ;Lookup DQLN
  689.  
  690. ;**************************************************************************
  691. ;       ADDA
  692. ;
  693. ; Add scale factor to log version of quantized difference
  694. ;   signal
  695. ;
  696. ; DQL(k) = DQLN(k) + Y(k)
  697. ;
  698. ; Inputs:
  699. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  700. ;   DQLN = siii i.fff | ffff 0000 | 0000 0000  (12TC)
  701. ;
  702. ; Output:
  703. ;   DQL = siii i.fff | ffff ffff | ffff ffff  (24TC)
  704. ;
  705. ;**************************************************************************
  706.  
  707.         ADD     B,A                 ;Find DQL=DQLN+Y
  708.    
  709. ;**************************************************************************
  710. ;       ANTILOG
  711. ;
  712. ; Convert quantized difference signal from log to linear
  713. ;   domain. Use approximation 2**(x) = 1 + x
  714. ;
  715. ; Input:
  716. ;   DQL = siii i.fff | ffff ffff | ffff ffff  (24TC)
  717. ;   DQS = sXXX 0000 | 0000 0000 | 0000 0000  (1TC)
  718. ;
  719. ; Outputs:
  720. ;   DQ = siii iiii | iiii iii.f | ffff ffff  (24SM)
  721. ;
  722. ;**************************************************************************
  723.  
  724.         JPL     <CONVLOG            ;If DQL>=0 convert DQL,
  725.                                     ; else DQL<0, set |DQ|=0
  726.         TFR     Y1,A    #<$80,X0    ;Get DQS (MSB of I), get mask
  727.         AND     X0,A    #0,B        ;Mask off DQS, set |DQ|=0
  728.         MOVE    B1,Y:DQMAG          ;Save DQMAG=|DQ|
  729.         JMP     <SAVEDQ
  730.  
  731. CONVLOG
  732.         TFR     A,B     #$07FFFF,X0 ;Get mask
  733.         AND     X0,A    #<$08,X1    ;Find fractional part (DMN), get '1'
  734.         OR      X1,A    #<$78,X0    ;Add '1' to DMN to find DQT,
  735.                                     ; get integer mask
  736.         AND     X0,B    Y:RSHFT+19,Y0   ;Find integer part (DEX),
  737.                                     ; get shift constant
  738.         MOVE    B1,X0
  739.         MPY     X0,Y0,B     #>$0A,X0    ;Shift DEX>>19, get '10'
  740.         SUB     X0,B        #$7FFFFF,X0 ;Find DQT shift=DEX-10
  741.         JEQ     <TRUNCDQM           ;If DEX=10, no shift
  742.         JLT     <SHFRDQ             ;If DEX<10, shift right
  743.         REP     B1                  ;Else shift DQT left
  744.         LSL     A                   ; up to 4 times
  745.         JMP     <TRUNCDQM
  746.  
  747. SHFRDQ  NEG     B       #RSHFT,R0   ;Find 10-DEX
  748.         MOVE    B1,N0               ;Use 10-DEX for shift lookup
  749.         MOVE    A1,Y0
  750.         MOVE    Y:(R0+N0),X1        ;Lookup shift constant
  751.         MPY     X1,Y0,A             ;Shift DQT right up to 9 times
  752. TRUNCDQM    AND X0,A    #<$80,B     ;Truncate to find DQMAG=|DQ|,
  753.                                     ; get sign mask
  754.         AND     Y1,B    A1,Y:DQMAG  ;Mask off DQS, save DQMAG           
  755.         MOVE    B1,X0
  756.         OR      X0,A                ;Add DQS to DQMAG to get DQ
  757.                                     ;Note: result in A1, not A
  758. SAVEDQ  RTS
  759.  
  760. ;**************************************************************************
  761. ;       TRANS
  762. ;
  763. ; Transition detector
  764. ;
  765. ; TR(k) = 1 if TD(k)=1 and |DQ(k)|> 24 x 2**(YL(k))
  766. ;         0 otherwise
  767. ;
  768. ; Inputs:
  769. ;   TD = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  770. ;   YL = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  771. ;   DQ = siii iiii | iiii iii.f | ffff ffff  (24SM)
  772. ;
  773. ; Output:
  774. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  775. ;
  776. ;**************************************************************************
  777.  
  778. TRANS   TST     A   #0,A            ;Check TD, set TR=0
  779.         JEQ     <SAVETR             ;If TD=0 save TR=0
  780.                                     ; else test DQ and YL
  781.         TFR     B,A     #$07FFFF,X0 ;Save YL, get mask
  782.         AND     X0,A    #<$08,X0    ;Find YLFRAC (YL>>10), get '1'
  783.         OR      X0,A    B,X1        ;Add implied '1' to YLFRAC,
  784.         MOVE    Y:RSHFT+19,Y1       ;Get shift const
  785.         MPY     Y1,X1,B     #>$08,X0    ;Find YLINT=YL>>19, get '8'
  786.         MOVE    B1,B                ;Clear fractional portion
  787.         CMP     X0,B    #>$05,X0    ;Compare YLINT to '8', get '5'
  788.         JGT     <MAXTHR             ;If YLINT>8 set maximum THR2
  789.         SUB     X0,B                ;Find YLINT-5
  790.         JEQ     <SETDQTHR           ;If YLINT=5 don't shift
  791.         JLT     <RSHIFT             ;If YLINT<5 shift right
  792.  
  793.         REP     B1                  ;Else shift YLFRAC left
  794.         LSL     A                   ; up to 3 times to get THR1
  795.         JMP     <SETDQTHR
  796.  
  797. MAXTHR  MOVE    #<$7C,A             ;Set maximum THR1
  798.         JMP     <SETDQTHR
  799.  
  800. RSHIFT  NEG     B       #RSHFT,R0   ;Find 5-YLINT
  801.         MOVE    B1,N0               ;Use 5-YLINT for shift lookup
  802.         MOVE    A1,X0
  803.         MOVE    Y:(R0+N0),X1        ;Lookup shift constant
  804.         MPY     X0,X1,A             ;Shift YLFRAC right up to 5 times
  805.                                     ; to get THR1
  806. SETDQTHR    TFR     A,B             ;Copy THR1=2**(YL)
  807.         ADDR    B,A     #0,X1
  808.         ASR     A       Y:DQMAG,X0  ;Find DQTHR='24' x 2**(YL)
  809.         CMP     X0,A    #<$80,A     ;Compare DQMAG to DQTHR, set TR=1
  810.         TGT     X1,A                ;If DQMAG>DQTHR leave TR=1,
  811.                                     ; else DQMAG<=DQTHR, set TR=0
  812. SAVETR  RTS
  813.  
  814. ;**************************************************************************
  815. ;       ADDB
  816. ;
  817. ; Add quantized difference signal and signal estimate
  818. ;   to form reconstructed signal
  819. ;
  820. ; SR(k-n) = SE(k-n) + DQ(k-n)
  821. ;
  822. ; Inputs:
  823. ;   DQ = siii iiii | iiii iii.f | ffff ffff  (24SM)
  824. ;   SE = siii iiii | iiii iiii. | ffff ffff  (24TC)
  825. ;
  826. ; Output:
  827. ;   SR = siii iiii | iiii iiii. | ffff ffff  (24TC)
  828. ;
  829. ;**************************************************************************
  830.  
  831. ADDBC   TST     A       Y:DQMAG,A   ;Check DQS, get DQMAG
  832.         JPL     <SHFTDQ             ;If DQS=0 continue
  833.         NEG     A                   ;Convert DQ to 2's comp
  834. SHFTDQ  ADDR    B,A     A,B         ;Find SR=DQ+SE, save DQ
  835.         TFR     B,A     A,X1        ;Swap DQ and SR
  836.  
  837. ;**************************************************************************
  838. ;       ADDC
  839. ;
  840. ; Obtain sign of addition of the quantized difference
  841. ;   signal and the partial signal estimate
  842. ;
  843. ; P(k) = DQ(k) + SEZ(k)
  844. ; PK0 = sign of P(k)
  845. ;
  846. ; Inputs:
  847. ;   DQ = siii iiii | iiii iii.0 | 0000 0000  (15SM)
  848. ;   SEZ = siii iiii | iiii iiii. | ffff ffff (24TC)
  849. ;
  850. ; Output:
  851. ;   PK0 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  852. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  853. ;
  854. ;**************************************************************************
  855.  
  856.         ADD     X0,A    #0,B        ;Find DQSEZ=DQ+SEZ,
  857.                                     ; set SIGPK=0
  858.         TST     A   #<$80,X0        ;Check DQSEZ, get '1'
  859.         TEQ     X0,B                ;If DQSEZ=0, SIGPK=1,
  860.                                     ; else SIGPK=0
  861.         MOVE    Y:(R0)-,Y1          ;Get PK1
  862.         MOVE    Y:(R0)+,X0          ;Get PK0
  863.         MOVE    X0,Y:(R0)-          ;Delay previous PK0
  864.         EOR     X0,A    A1,Y:(R0)   ;Save new PK0, find PKS1=PK0**PK1
  865.                                     ; for UPA1 & UPA2
  866.         MOVE    A1,X:PKS1           ;Save PKS1
  867.         MOVE    Y:(R0),A
  868.         EOR     Y1,A                ;Find PKS2=PK0**PK2 for UPA2
  869.         MOVE    A1,X:PKS2           ;Save PKS2
  870.         RTS
  871.  
  872. ;**************************************************************************
  873. ;       XOR/UPB
  874. ;
  875. ; Update the coefficients of the sixth order predictor
  876. ;
  877. ; Bn(k) = [1-(2**-8)] * Bn(k-1)
  878. ;           + (2**-7) * sgn[DQ(k)] * sgn[DQ(k-n)]
  879. ; Un = sgn[DQ(k)] XOR sgn[DQ(k-n)]
  880. ;
  881. ; Inputs:
  882. ;   Bn = Y:(R6+n) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  883. ;   DQ = siii iiii | iiii iii.f | ffff ffff (24SM)
  884. ;
  885. ; Outputs:
  886. ;   BnP = Y:(R6+n) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  887. ;
  888. ;**************************************************************************
  889.  
  890. UPB     MOVE    Y:DQMAG,B
  891.         MOVE    #$008000,X0         ;Get +gain
  892.         DO      #6,ENDUPB           ;Do UPB and XOR for B1-B6
  893.         MOVE    X:(R2)+,A       Y:(R6),Y1   ;Get Bn & DQnS
  894.         EOR     Y0,A    #$FF8000,X1 ;Find Un=DQS**DQnS (XOR),
  895.                                     ; get -gain
  896.         TPL     X0,A                ;If Un=0 set UGBn=+gain
  897.         TMI     X1,A                ;If Un=1 set UGBn=-gain
  898.         TST     B       #0,X1       ;Test for |DQ|=0
  899.         TEQ     X1,A                ;If |DQ|=0, Then UGBn=0
  900.         MOVE    Y:RSHFT+8,X1        ;Get shift constant
  901.         MAC     -X1,Y1,A            ;Find UBn=UGBn-(Bn>>8)
  902.         ADD     Y1,A                ;Find BnP=Bn+UBn
  903.         MOVE    A1,Y:(R6)+          ;Store BnP to Bn
  904. ENDUPB  RTS
  905.  
  906. ;**************************************************************************
  907. ;       UPA2
  908. ;
  909. ; Update the A2 coefficient of the second order predictor.
  910. ;
  911. ; A2(k) = [1-(2**-7)] * A2(k-1)
  912. ;           + (2**-7) * { sgn[P(k)] * sgn[P(k-2)]
  913. ;               - F[A1(k-1)] * sgn[P(k)] * sgn[P(k-1)] }
  914. ;
  915. ; F[A1(k)] = 4 * A1       if |A1|<=(2**-1)
  916. ;          = 2 * sgn(A1)  if |A1|>(2**-1)
  917. ;
  918. ; Inputs:
  919. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  920. ;   A2 = Y:(R6+1) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  921. ;   SIGPK = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  922. ;   PK0 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  923. ;   PK1 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  924. ;   PK2 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  925. ;     (Note: PKS1 & PKS2 have been previously calculated)
  926. ;
  927. ; Outputs:
  928. ;   A2T = si.ff ffff | ffff ffff | ffff ffff (24TC)
  929. ;
  930. ;**************************************************************************
  931.  
  932. UPA2    MOVE    X:PKS2,A            ;Get PKS2=PK0**PK2
  933.         MOVE    #<$10,Y0            ;Get '+1'
  934.         TST     A   #<$F0,Y1        ;Check PKS2, get '-1'
  935.         TPL     Y0,A                ;If PKS2=0, set UGA2A='+1'
  936.         TMI     Y1,A                ;If PKS2=1, set UGA2A='-1'
  937.         MOVE    A,X1    Y:(R6)+,A   ;Save UGA2A, get A1
  938.         MOVE    #$1FFF00,Y0         ;Get '+1.99'
  939.         CMP     Y0,A    #$E00100,Y1 ;Check A1, get '-1.99'
  940.         TGT     Y0,A                ;If A1>=1/2, set FA1='1.99'
  941.         CMP     Y1,A    X:PKS1,B    ;Check A1 again, get PKS1=PK0**PK1
  942.         TLT     Y1,A                ;If A1<=-1/2, set FA1='-1.99'
  943.         TST     B                   ;Check PKS1
  944.         JMI     <FINDSUM            ;If PKS1=1, FA=FA1
  945.         NEG     A                   ; else PKS1=0, set FA=-FA1
  946. FINDSUM ADD     X1,A    Y:RSHFT+5,Y1    ;Find UGA2B=UGA2A+FA
  947.         TFR     X0,B    A,X1
  948.         MPY     X1,Y1,A     #0,X0   ;Find UGA2B>>7
  949.         TST     B   Y:(R6),Y0       ;Check SIGPK, get A2
  950.         TMI     X0,A                ;If SIGPK=1, set UGA2=0
  951.         MOVE    Y:RSHFT+7,X0        ;Get shift constant
  952.         MAC     -Y0,X0,A            ;Find UA2=UGA2-(A2>>7)
  953.         ADD     Y0,A                ;Find A2T=A2+UA2
  954.  
  955. ;**************************************************************************
  956. ;       LIMC
  957. ;
  958. ; Limit the A2 coefficient of the second order predictor.
  959. ;
  960. ;   |A2(k)| <= '0.75' 
  961. ;
  962. ; Inputs:
  963. ;   A2T = si.ff ffff | ffff ffff | ffff ffff (24TC)
  964. ;
  965. ; Outputs:
  966. ;   A2P = Y:(R6) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  967. ;
  968. ;**************************************************************************
  969.  
  970.         MOVE    #<$D0,X0            ;Get A2LL
  971.         CMP     X0,A    #<$30,X1    ;Check A2P, get A2UL
  972.         TLT     X0,A                ;If A2P<-0.75, set A2P=-0.75
  973.         CMP     X1,A                ;Check A2P again
  974.         TGT     X1,A                ;If A2P>0.75, set A2P=0.75
  975.         RTS
  976.  
  977. ;**************************************************************************
  978. ;       UPA1
  979. ;
  980. ; Update the A1 coefficient of the second order predictor.
  981. ;
  982. ; A1(k) = [1-(2**-8)] * A1(k-1)
  983. ;           + 3 * (2**-8) * sgn[P(k)] * sgn[P(k-1)]
  984. ;
  985. ; Inputs:
  986. ;   A1 = Y:(R6) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  987. ;   SIGPK = Y:(R0) = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  988. ;   PK0 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  989. ;   PK1 = sXXX XXXX | XXXX XXXX | XXXX XXXX  (1TC)
  990. ;     (Note: PKS1 has been previously calculated)
  991. ;
  992. ; Outputs:
  993. ;   A1T = si.ff ffff | ffff ffff | ffff ffff (24TC)
  994. ;
  995. ;**************************************************************************
  996.  
  997. UPA1    MOVE    #$00C000,Y0         ;Get +gain
  998.         MOVE    X:PKS1,B            ;Get PKS1=PK0**PK1
  999.         TST     B       #$FF4000,Y1 ;Check PKS1, get -gain
  1000.         TPL     Y0,A                ;If PKS=0, set UGA1=+gain
  1001.         TMI     Y1,A                ;If PKS=1, set UGA1=-gain
  1002.         MOVE    X1,B
  1003.         TST     B       #0,X1       ;Check SIGPK
  1004.         TMI     X1,A                ;If SIGPK=1, set UGA1=0
  1005.         MOVE    Y:(R6),X1           ;Get A1
  1006.         MOVE    Y:RSHFT+8,Y0        ;Get shift constant
  1007.         MAC     -Y0,X1,A            ;Find UA1=UGA1-(A1>>8)
  1008.         ADD     X1,A                ;Find A1T=A1+UA1
  1009.  
  1010. ;**************************************************************************
  1011. ;       LIMD
  1012. ;
  1013. ; Limit the A1 coefficient of the second order predictor.
  1014. ;
  1015. ;   |A1(k)| <= [1-(2**-4)] - A2(k)
  1016. ;
  1017. ; Inputs:
  1018. ;   A1T = si.ff ffff | ffff ffff | ffff ffff (24TC)
  1019. ;   A2P = si.ff ffff | ffff ffff | ffff ffff (24TC)
  1020. ;
  1021. ; Outputs:
  1022. ;   A1P = Y:(R6) = si.ff ffff | ffff ffff | ffff ffff (24TC)
  1023. ;
  1024. ;**************************************************************************
  1025.  
  1026.         MOVE    #<$3C,B             ;Get OME='1-(2**-4)'
  1027.         SUB     X0,B                ;Find A1UL=OME-A2P
  1028.         CMP     B,A     B,X0        ;Check A1T
  1029.         TGT     X0,A                ;If A1T>A1UL, set A1P=A1UL
  1030.         NEG     B       #2,N6       ;Find A1LL=-A1UL=A2P-OME
  1031.         CMP     B,A     B,X0        ;Check A1T again
  1032.         TLT     X0,A                ;If A1T<A1LL, set A1P=A1LL
  1033.         MOVE    A1,Y:(R6)+N6        ;Store A1P to A1
  1034.         RTS
  1035.  
  1036. ;**************************************************************************
  1037. ;       FLOATA
  1038. ;
  1039. ; Convert the quantized difference signal from signed magnitude
  1040. ;   to two's complement and save to the data buffer.
  1041. ;
  1042. ; Inputs:
  1043. ;   DQ = siii iiii | iiii iii.f | ffff ffff (24SM)
  1044. ;
  1045. ; Outputs:
  1046. ;   DQ = X:(R2) = siii iiii | iiii iiii. | ffff ffff (24TC)
  1047. ;
  1048. ;**************************************************************************
  1049.  
  1050. FLOAT   TST     A       #2,N2       ;Test sign of DQ
  1051.         JPL     <TRUNCDQ
  1052.         MOVE    Y:DQMAG,A           ;If DQ<0,
  1053.         NEG     A                   ; negate magnitude of DQ
  1054. TRUNCDQ ASR     A       (R2)+       ;Sign extend to 16TC
  1055.         MOVE    A,X:(R2)-N2
  1056.  
  1057. ;**************************************************************************
  1058. ;       FLOATB
  1059. ;
  1060. ; Save the reconstructed signal to the data buffer.
  1061. ;
  1062. ; Inputs:
  1063. ;   SR = siii iiii | iiii iiii. | ffff ffff  (24TC)
  1064. ;
  1065. ; Outputs:
  1066. ;   SR = X:(R2) = siii iiii | iiii iiii. | ffff ffff  (24TC)
  1067. ;
  1068. ;**************************************************************************
  1069.  
  1070.         MOVE    B,X:(R2)+N2
  1071.         RTS
  1072.  
  1073. ;**************************************************************************
  1074. ;       TONE
  1075. ;
  1076. ; Partial band signal detection
  1077. ;
  1078. ; TD(k) = 1 if A2(k) < -0.71875
  1079. ;         0 otherwise
  1080. ;
  1081. ; Inputs:
  1082. ;   A2P = si.ff ffff | ffff ffff | ffff ffff  (24TC)
  1083. ;
  1084. ; Output:
  1085. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1086. ;
  1087. ;**************************************************************************
  1088.  
  1089. TONE    CLR     A   #<$D2,X0        ;Get '-.71875', set TDP=0
  1090.         CMP     X0,B    #<$80,X1    ;Check A2P, get '1'
  1091.         TLT     X1,A                ;If A2P<-.71875 set TDP=1, else TDP=0
  1092.  
  1093. ;**************************************************************************
  1094. ;       TRIGB
  1095. ;
  1096. ; Predictor trigger block
  1097. ;
  1098. ; If TR(k) = 1, An(k)=Bn(k)=TD(k)=0
  1099. ;
  1100. ; Inputs:
  1101. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1102. ;   BnP = si.ff ffff | ffff ffff | ffff ffff  (24TC)
  1103. ;   AnP = si.ff ffff | ffff ffff | ffff ffff  (24TC)
  1104. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1105. ;
  1106. ; Output:
  1107. ;   BnR = si.ff ffff | ffff ffff | ffff ffff  (24TC)
  1108. ;   AnR = si.ff ffff | ffff ffff | ffff ffff  (24TC)
  1109. ;   TDR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1110. ;
  1111. ;**************************************************************************
  1112.  
  1113.         MOVE    Y0,B
  1114.         TST     B       A,Y1        ;Test TR
  1115.         JEQ     <ENDTRIG
  1116.         CLR     A                   ;If TR=1, set TDR=0,
  1117.         REP     #8                  ; and B1-B6,A1,A2=0
  1118.         MOVE    A,Y:(R6)+
  1119. ENDTRIG RTS
  1120.  
  1121. ;**************************************************************************
  1122. ;       FUNCTF
  1123. ;
  1124. ; Maps quantizer output I into F(I) function
  1125. ;
  1126. ;  |I(k)|  | 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |
  1127. ; ---------+---+---+---+---+---+---+---+---+
  1128. ;  F[I(k)] | 7 | 3 | 1 | 1 | 1 | 0 | 0 | 0 |
  1129. ;
  1130. ; Inputs:
  1131. ;   I = siii. 0000 | 0000 0000 | 0000 0000
  1132. ;
  1133. ; Output:
  1134. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1135. ;
  1136. ;**************************************************************************
  1137.  
  1138. FUNCTF  MOVE    #FIBASE,R0          ;Load lookup table base
  1139.         MOVE    X:IMAG,N0           ;Load IMAG as offset
  1140.         NOP
  1141.         MOVE    X:(R0+N0),A         ;Get FI from lookup table
  1142.  
  1143. ;**************************************************************************
  1144. ;       FILTA
  1145. ;
  1146. ; Update short term average of F(I)
  1147. ;
  1148. ; DMS(k) = (1 - 2**(-5)) * DMS(k-1) + 2**(-5) * F[I(k)]
  1149. ;
  1150. ; Inputs:
  1151. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1152. ;   DMS = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1153. ;
  1154. ; Output:
  1155. ;   DMSP = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1156. ;
  1157. ;**************************************************************************
  1158.  
  1159.         SUB     Y0,A    A,B         ;Find DIF=FI-DMS, save FI
  1160.         TFR     Y0,A    A,X0        ;Move DIF and DMS
  1161.         MOVE    Y:RSHFT+5,X1        ;Get mask
  1162.         MAC     X0,X1,A             ;Find DMSP=(DIF>>5)+DMS
  1163.  
  1164. ;**************************************************************************
  1165. ;       FILTB
  1166. ;
  1167. ; Update long term average of F(I)
  1168. ;
  1169. ; DML(k) = (1 - 2**(-7)) * DML(k-1) + 2**(-7) * F[I(k)]
  1170. ;
  1171. ; Inputs:
  1172. ;   FI = 0iii. 0000 | 0000 0000 | 0000 0000  (3SM)
  1173. ;   DML = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1174. ;
  1175. ; Output:
  1176. ;   DMLP = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1177. ;
  1178. ;**************************************************************************
  1179.  
  1180.         SUB     Y1,B    Y:RSHFT+7,X1    ;Find DIF=FI-DML
  1181.         TFR     Y1,B    B,X0
  1182.         MAC     X0,X1,B             ;Find DMLP=(DIF>>7)+DML
  1183.         RTS
  1184.  
  1185. ;**************************************************************************
  1186. ;       SUBTC
  1187. ;
  1188. ; Compute magnitude of the difference of short and long
  1189. ;  term functions of quantizer output sequence and then
  1190. ;  perform threshold comparison for quantizing speed control
  1191. ;  parameter.
  1192. ;
  1193. ; AX = 1  if Y(k)>=3, TD(k)=1, & |DMS(k)-DML(k)|>(2**-3)*DML(k)
  1194. ;    = 0  otherwise
  1195. ;
  1196. ; Input:
  1197. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1198. ;   DMSP = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1199. ;   DMLP = 0iii. ffff | ffff ffff | ffff ffff  (23SM)
  1200. ;   TDP = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1201. ;
  1202. ; Output:
  1203. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  1204. ;
  1205. ;**************************************************************************
  1206.  
  1207. SUBTC   SUB     B,A     Y:RSHFT+3,X0    ;Find DIF=DMSP-DMLP
  1208.         ABS     A       B,Y0        ;Find DIFM=|DIF|
  1209.         MPY     X0,Y0,B     #<$40,X0    ;Find DTHR=DMLP>>3, get '1'
  1210.         CMP     B,A     #0,B        ;Compare DIFM & DTHR, set AX=0
  1211.         TGE     X0,B                ;If DIFM>=DTHR set AX=1
  1212.         MOVE    X1,A                ;Get TDP
  1213.         TST     A       #<$18,Y0    ;Check TDP, get '3'
  1214.         TNE     X0,B                ;If TDP!=0 set AX=1
  1215.         MOVE    Y1,A
  1216.         CMP     Y0,A                ;Check for Y<"3"
  1217.         TLT     X0,B                ;If Y<"3" set AX=1
  1218.         RTS
  1219.  
  1220. ;**************************************************************************
  1221. ;       FILTC
  1222. ;
  1223. ; Low pass filter of speed control parameter
  1224. ;
  1225. ; AP(k) = (1-2**(-4)) * AP(k-1) + AX
  1226. ;
  1227. ; Inputs:
  1228. ;   AX = 0i0.0 0000 | 0000 0000 | 0000 0000  (1SM)
  1229. ;   AP = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  1230. ;
  1231. ; Outputs:
  1232. ;   APP = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  1233. ;
  1234. ;**************************************************************************
  1235.  
  1236. FILTC   SUB     X1,B    Y:RSHFT+4,Y0    ;Find DIF=AX-AP
  1237.         TFR     X1,A    B,X0
  1238.         MAC     X0,Y0,A                 ;Find APP=(DIF>>4)+AP
  1239.  
  1240. ;**************************************************************************
  1241. ;       TRIGA
  1242. ;
  1243. ; Speed control trigger block
  1244. ;
  1245. ; AP(k) = AP(k) if TR(k)=0
  1246. ;       =  1    if TR(k)=1
  1247. ;
  1248. ; Inputs:
  1249. ;   TR = i000 0000 | 0000 0000 | 0000 0000  (1TC)
  1250. ;   APP = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  1251. ;
  1252. ; Outputs:
  1253. ;   APR = 0ii.f ffff | ffff ffff | ffff ffff  (23SM)
  1254. ;
  1255. ;**************************************************************************
  1256.  
  1257.         MOVE    Y1,B
  1258.         TST     B       #<$20,X0    ;Check TR, get '1'
  1259.         TMI     X0,A                ;If TR=1 set APR=1, else APR=APP
  1260.         RTS
  1261.  
  1262. ;**************************************************************************
  1263. ;       FUNCTW
  1264. ;
  1265. ; Map quantizer output into logarithmic version of scale
  1266. ;  factor multiplier
  1267. ;
  1268. ;  |I(k)|  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
  1269. ; ---------+-----+-----+-----+-----+-----+-----+-----+-----+
  1270. ;   W(I)   |70.13|22.19|12.38| 7.00| 4.00| 2.56| 1.13|-0.75|
  1271. ;
  1272. ; Inputs:
  1273. ;   I = siii. 0000 | 0000 0000 | 0000 0000
  1274. ;
  1275. ; Outputs:
  1276. ;   WI = siii iiii. | ffff 0000 | 0000 0000  (12TC)
  1277. ;
  1278. ;**************************************************************************
  1279.  
  1280. FUNCTW  MOVE    #WIBASE,R0          ;Load lookup table base
  1281.         MOVE    X:IMAG,N0           ;Load IMAG as offset
  1282.         NOP
  1283.         MOVE    X:(R0+N0),A         ;Get WI from lookup table
  1284.  
  1285. ;**************************************************************************
  1286. ;       FILTD
  1287. ;
  1288. ; Update of fast quantizer scale factor
  1289. ;
  1290. ; YU(k) = (1 - 2**(-5)) * Y(k) + 2**(-5) * W[I(k)]
  1291. ;
  1292. ; Inputs:
  1293. ;   WI =  siii iiii. | ffff 0000 | 0000 0000  (12TC)
  1294. ;   Y = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1295. ;
  1296. ; Outputs:
  1297. ;   YUT = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1298. ;
  1299. ;**************************************************************************
  1300.  
  1301.         MOVE    Y:RSHFT+3,X1        ;Get shift constant
  1302.         MAC     -Y0,X1,A    Y0,B    ;Find DIF=WI-(Y>>3)
  1303.         ASR     A
  1304.         ADDR    B,A                 ;Find YUT=(DIF>>5)+Y (actually DIF>>2)
  1305.  
  1306. ;**************************************************************************
  1307. ;       LIMB
  1308. ;
  1309. ; Limit quantizer scale factor
  1310. ;
  1311. ; 1.06 <= YU(k) <= 10.00
  1312. ;
  1313. ; Inputs:
  1314. ;   YUT = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1315. ;
  1316. ; Outputs:
  1317. ;   YUP = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1318. ;
  1319. ;**************************************************************************
  1320.  
  1321.         MOVE    #<$50,X0            ;Get upper limit '10'
  1322.         CMP     X0,A    #$088000,X1 ;Check for YU>10,
  1323.                                     ; get lower limit '1.06'
  1324.         TGT     X0,A                ;If YU>10 set YU=10
  1325.         CMP     X1,A                ;Check for YU<1.06
  1326.         TLT     X1,A                ;If YU<1.06 set YU=1.06
  1327.         MOVE    A,X0                ;Save YUP
  1328.  
  1329. ;**************************************************************************
  1330. ;       FILTE
  1331. ;
  1332. ; Update of slow quantizer scale factor
  1333. ;
  1334. ; YL(k) = (1 - 2**(-6)) * YL(k-1) + 2**(-6) * YU(k)
  1335. ;
  1336. ; Inputs:
  1337. ;   YUP = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1338. ;   YL = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1339. ;
  1340. ; Outputs:
  1341. ;   YLP = 0iii i.fff | ffff ffff | ffff ffff  (23SM)
  1342. ;
  1343. ;**************************************************************************
  1344.  
  1345.         MOVE    Y1,B
  1346.         SUB     B,A     Y:RSHFT+6,Y0    ;Find DIF=YUP-YL
  1347.         TFR     B,A     A,X1
  1348.         MAC     Y0,X1,A                 ;Find YLP=(DIFSX>>6)+YL
  1349.         RTS
  1350.  
  1351. ;**************************************************************************
  1352. ;       COMPRESS
  1353. ;
  1354. ; Convert from uniform PCM to A-law or mu-law PCM (according to
  1355. ;   Recommendation G.711). For further details see Motorola
  1356. ;   application bulletin "Logarithmic/Linear Conversion
  1357. ;   Routines for DSP56000/1".
  1358. ;
  1359. ; Input:
  1360. ;   SR = siii iiii | iiii iiii. | 0000 0000  (16TC)
  1361. ;
  1362. ; Output:
  1363. ;   SP = psss qqqq | 0000 0000 | 0000 0000 (PCM log format)
  1364. ;
  1365. ;**************************************************************************
  1366.  
  1367. COMPRESS
  1368.         MOVE    #$002100,Y0         ;Get bias
  1369.         TST     B       X1,A
  1370.         JNE     <ALAW
  1371.  
  1372. ; Linear to log routine for mu-law
  1373.         ABS     A       A,B         ;Find |SR|, save sign
  1374.         ADD     Y0,A                ;Add bias
  1375.         ASL     A   #TAB+7,R0       ;Shift << 2, get seg ptr
  1376.         ASL     A   X:TAB+3,X0      ; and get max. word
  1377.         TES     X0,A                ;If overflow in extension
  1378.                                     ; set the maximum PCM word
  1379.         REP     #7                  ;Find MSB of data
  1380.         NORM    R0,A
  1381.         ASL     A       #<$20,Y0
  1382.         LSL     B       A1,X0
  1383.         MPY     X0,Y0,A     X:(R0),X1
  1384.         AND     X1,A
  1385.         ROR     A
  1386.         NOT     A       #<$FF,X0
  1387.         AND     X0,A
  1388.         MOVE    A1,A
  1389.         JMP     <SAVESP
  1390.  
  1391. ; Linear to log routine for A-law
  1392. ALAW    MOVE    #$FFFF00,X0
  1393.         AND     X0,A
  1394.         ABS     A       A,B         ;Find |SR|, save sign
  1395.         TST     B       #$000100,X0
  1396.         JPL     <NOSUB
  1397.         SUB     X0,A
  1398. NOSUB   MOVE    #$7FFE00,X0
  1399.         AND     X0,A
  1400.         ASL     A   #TAB+7,R0       ;Shift << 2, get seg ptr
  1401.         ASL     A   X:TAB+3,X0      ; and get max. word
  1402.         TES     X0,A                ;If overflow in extension
  1403.                                     ; set the maximum PCM word
  1404.         REP     #6                  ;Find MSB of data
  1405.         NORM    R0,A
  1406.         JNR     <SEGOK
  1407.         MOVE    (R0)-
  1408. SEGOK   LSL     A       #<$20,Y0
  1409.         LSL     B       A1,X0
  1410.         MPY     X0,Y0,A     X:(R0),X1
  1411.         AND     X1,A
  1412.         ROR     A       #<$D5,Y1
  1413.         EOR     Y1,A    #<$FF,X0    ;Invert even bits & sign
  1414.         AND     X0,A
  1415.         MOVE    A1,A
  1416. SAVESP  RTS
  1417.  
  1418. ;**************************************************************************
  1419. ;       INIT
  1420. ;
  1421. ; Initialize program variables, transfer data tables to X and Y
  1422. ; memory, and set up registers
  1423. ;
  1424. ;**************************************************************************
  1425.  
  1426. INIT    MOVE    A,R0
  1427.         REP     #$7F                ;Clear internal data RAM
  1428.         MOVE    A,L:(R0)+
  1429.  
  1430. ; X memory initialization
  1431.  
  1432.         MOVE    #DATA_T,A0          ;Set transmit data pointer
  1433.         MOVE    A0,X:DATAPTR_T      ; to start of transmit data buffer
  1434.         MOVE    #DATA_R,A0          ;Set receive data pointer
  1435.         MOVE    A0,X:DATAPTR_R      ; to start of receive data buffer
  1436.  
  1437.         MOVE    #$3E2000,X0
  1438.         MOVE    X0,X:AP_T           ;Initialize speed control parameters
  1439.         MOVE    X0,X:AP_R
  1440.  
  1441.         MOVE    #VARINIT,R0         ;Copy constant tables into
  1442.         MOVE    #QUANTAB,R3         ; X memory
  1443.         DO      #40,XTABLES
  1444.         MOVE    P:(R0)+,X0
  1445.         MOVE    X0,X:(R3)+
  1446. XTABLES
  1447.  
  1448. ; Y memory initialization
  1449.  
  1450.         MOVE    #$088000,X0
  1451.         MOVE    X0,Y:YU_T           ;Initialize quantizer scale factors
  1452.         MOVE    X0,Y:YL_T
  1453.         MOVE    X0,Y:YU_R
  1454.         MOVE    X0,Y:YL_R
  1455.  
  1456.         MOVE    #RSHFT,R3           ;Copy shift constant table into
  1457.         DO      #24,YTABLES         ; Y memory
  1458.         MOVE    P:(R0)+,X0
  1459.         MOVE    X0,Y:(R3)+
  1460. YTABLES
  1461.  
  1462.         MOVEC   #7,M2               ;Set data buffer for mod(7)
  1463.         MOVEC   #7,M6               ;Set coef buffer for mod(7)
  1464.         MOVEC   #$7F,M3             ;Set PCM table for mod(127)
  1465.         MOVE    #0,A                ;Select mu-law or A-law,
  1466.         MOVE    A,Y:LAW             ; for mu-law set LAW=0 (default),
  1467.                                     ; for A-law set LAW!=0
  1468.         TST     A       #$100,R3    ;If LAW=0 select mu-law table
  1469.         JEQ     <IOINIT             ; base (in X ROM), otherwise
  1470.         MOVE    #$180,R3            ; select A-law table base
  1471.  
  1472. IOINIT  MOVEP   #$00000F,X:PBD      ;Initialize PB0..3
  1473.         MOVEP   #$00000F,X:PBDDR    ;Set PB0..3 for outputs
  1474.  
  1475.         MOVEP   #$003200,X:CRB      ;Set up SSI mode
  1476.         MOVEP   #$000000,X:CRA      ;Set up SSI rate
  1477.         MOVEP   #$0001E0,X:PCC      ;Enable SSI output pins
  1478.         MOVEP   #0,X:SSITX          ;Dummy write to SSI transmitter
  1479.         RTS
  1480.  
  1481. ; QUANTAB
  1482. VARINIT     DC      $F84000         ;-0.98
  1483.             DC      $050000         ;0.62
  1484.             DC      $0B2000         ;1.38
  1485.             DC      $0F6000         ;1.91
  1486.             DC      $12C000         ;2.34
  1487.             DC      $15D000         ;2.72
  1488.             DC      $190000         ;3.12
  1489.             DC      $7FFFFF         ;15.99
  1490.  
  1491. ; IQUANTAB
  1492.             DC      $800000         ;-16    |I|=0
  1493.             DC      $004000         ;0.031  |I|=1
  1494.             DC      $087000         ;1.05   |I|=2
  1495.             DC      $0D5000         ;1.66   |I|=3
  1496.             DC      $111000         ;2.13   |I|=4
  1497.             DC      $143000         ;2.52   |I|=5
  1498.             DC      $175000         ;2.91   |I|=6
  1499.             DC      $1A9000         ;3.32   |I|=7
  1500.  
  1501. ; WIBASE
  1502.             DC      $FF4000         ;-0.75  |I|=0
  1503.             DC      $012000         ;1.13   |I|=1
  1504.             DC      $029000         ;2.56   |I|=2
  1505.             DC      $040000         ;4.00   |I|=3
  1506.             DC      $070000         ;7.00   |I|=4
  1507.             DC      $0C6000         ;12.38  |I|=5
  1508.             DC      $163000         ;22.19  |I|=6
  1509.             DC      $462000         ;70.13  |I|=7
  1510.  
  1511. ; FIBASE
  1512.             DC      $000000         ;0  |I|=0
  1513.             DC      $000000         ;0  |I|=1
  1514.             DC      $000000         ;0  |I|=2
  1515.             DC      $100000         ;1  |I|=3
  1516.             DC      $100000         ;1  |I|=4
  1517.             DC      $100000         ;1  |I|=5
  1518.             DC      $300000         ;3  |I|=6
  1519.             DC      $700000         ;7  |I|=7
  1520.  
  1521. ; TAB
  1522.             DC      $1E0000
  1523.             DC      $3E0000
  1524.             DC      $5E0000
  1525.             DC      $7E0000
  1526.             DC      $9E0000
  1527.             DC      $BE0000
  1528.             DC      $DE0000
  1529.             DC      $FE0000
  1530.  
  1531. ; RSHFT
  1532.             DC      $800000
  1533.             DC      $400000         ;>>1    <<23
  1534.             DC      $200000         ;>>2    <<22
  1535.             DC      $100000         ;>>3    <<21
  1536.             DC      $080000         ;>>4    <<20
  1537.             DC      $040000         ;>>5    <<19
  1538.             DC      $020000         ;>>6    <<18
  1539.             DC      $010000         ;>>7    <<17
  1540.             DC      $008000         ;>>8    <<16
  1541.             DC      $004000         ;>>9    <<15
  1542.             DC      $002000         ;>>10   <<14
  1543.             DC      $001000         ;>>11   <<13
  1544.             DC      $000800         ;>>12   <<12
  1545.             DC      $000400         ;>>13   <<11
  1546.             DC      $000200         ;>>14   <<10
  1547.             DC      $000100         ;>>15   <<9
  1548.             DC      $000080         ;>>16   <<8
  1549.             DC      $000040         ;>>17   <<7
  1550.             DC      $000020         ;>>18   <<6
  1551.             DC      $000010         ;>>19   <<5
  1552.             DC      $000008         ;>>20   <<4
  1553.             DC      $000004         ;>>21   <<3
  1554.             DC      $000002         ;>>22   <<2
  1555.             DC      $000001         ;>>23   <<1
  1556.